복붙노트

[SQL] SQL 서버 : 적절한 케이스 / 타이틀 케이스에 모든 UPPER 사례를 확인

SQL

SQL 서버 : 적절한 케이스 / 타이틀 케이스에 모든 UPPER 사례를 확인

나는 모든 대문자로 가져온 테이블을 가지고 있고 나는 적절한 사례로 돌려 싶습니다. 어떤 스크립트 당신의이을 완료하는 데 사용 있나요?

해결법

  1. ==============================

    1.여기에 트릭을 할 것 UDF의 ...

    여기에 트릭을 할 것 UDF의 ...

    create function ProperCase(@Text as varchar(8000))
returns varchar(8000)
as
begin
  declare @Reset bit;
  declare @Ret varchar(8000);
  declare @i int;
  declare @c char(1);

  if @Text is null
    return null;

  select @Reset = 1, @i = 1, @Ret = '';

  while (@i <= len(@Text))
    select @c = substring(@Text, @i, 1),
      @Ret = @Ret + case when @Reset = 1 then UPPER(@c) else LOWER(@c) end,
      @Reset = case when @c like '[a-zA-Z]' then 0 else 1 end,
      @i = @i + 1
  return @Ret
end

    당신은 여전히 ​​데이터 불구하고 업데이트하는 데 사용해야합니다.

  2. ==============================

    2.이 기능 :

    이 기능 :

    CREATE FUNCTION ToProperCase(@string VARCHAR(255)) RETURNS VARCHAR(255)
AS
BEGIN
  DECLARE @i INT           -- index
  DECLARE @l INT           -- input length
  DECLARE @c NCHAR(1)      -- current char
  DECLARE @f INT           -- first letter flag (1/0)
  DECLARE @o VARCHAR(255)  -- output string
  DECLARE @w VARCHAR(10)   -- characters considered as white space

  SET @w = '[' + CHAR(13) + CHAR(10) + CHAR(9) + CHAR(160) + ' ' + ']'
  SET @i = 1
  SET @l = LEN(@string)
  SET @f = 1
  SET @o = ''

  WHILE @i <= @l
  BEGIN
    SET @c = SUBSTRING(@string, @i, 1)
    IF @f = 1 
    BEGIN
     SET @o = @o + @c
     SET @f = 0
    END
    ELSE
    BEGIN
     SET @o = @o + LOWER(@c)
    END

    IF @c LIKE @w SET @f = 1

    SET @i = @i + 1
  END

  RETURN @o
END

    결과:

    dbo.ToProperCase('ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')
-----------------------------------------------------------------
All Upper Case and      Some lower Ää Öö Üü Éé Øø Cc Ææ
  3. ==============================

    3.

    UPDATE titles
  SET title =
      UPPER(LEFT(title, 1)) +
        LOWER(RIGHT(title, LEN(title) - 1))

    http://sqlmag.com/t-sql/how-title-case-column-value

  4. ==============================

    4.당신은 SQL Server의 CLR을 활성화 할 수 있다면 당신은 TextInfo.ToTitleCase를 사용하는 CLR 기능을 만들 수 있습니다 (2005 이상이 필요합니다) 내장 당신은 단지 몇에서이 일의 문화 인식의 방법을 만들 수있는 것입니다 기능 코드 라인.

    당신은 SQL Server의 CLR을 활성화 할 수 있다면 당신은 TextInfo.ToTitleCase를 사용하는 CLR 기능을 만들 수 있습니다 (2005 이상이 필요합니다) 내장 당신은 단지 몇에서이 일의 문화 인식의 방법을 만들 수있는 것입니다 기능 코드 라인.

  5. ==============================

    5.나는이 말이 스레드에 게시하지만, 가치 찾고 알고있다. 이 기능은 내가 이제까지 시간 동안 작동합니다. 그래서 그것을 공유 생각했다.

    나는이 말이 스레드에 게시하지만, 가치 찾고 알고있다. 이 기능은 내가 이제까지 시간 동안 작동합니다. 그래서 그것을 공유 생각했다.

    CREATE FUNCTION [dbo].[fnConvert_TitleCase] (@InputString VARCHAR(4000) )
RETURNS VARCHAR(4000)
AS
BEGIN
DECLARE @Index INT
DECLARE @Char CHAR(1)
DECLARE @OutputString VARCHAR(255)

SET @OutputString = LOWER(@InputString)
SET @Index = 2
SET @OutputString = STUFF(@OutputString, 1, 1,UPPER(SUBSTRING(@InputString,1,1)))

WHILE @Index <= LEN(@InputString)
BEGIN
    SET @Char = SUBSTRING(@InputString, @Index, 1)
    IF @Char IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&','''','(')
    IF @Index + 1 <= LEN(@InputString)
BEGIN
    IF @Char != ''''
    OR
    UPPER(SUBSTRING(@InputString, @Index + 1, 1)) != 'S'
    SET @OutputString =
    STUFF(@OutputString, @Index + 1, 1,UPPER(SUBSTRING(@InputString, @Index + 1, 1)))
END
    SET @Index = @Index + 1
END

RETURN ISNULL(@OutputString,'')
END

    테스트 전화 :

    select dbo.fnConvert_TitleCase(Upper('ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')) as test
select dbo.fnConvert_TitleCase(upper('Whatever the mind of man can conceive and believe, it can achieve. – Napoleon hill')) as test

    결과 :

  6. ==============================

    6.나는 조금 늦게 게임에서,하지만 난이 더 많은 기능이라고 생각하며 러시아어, 독일어, 태국어, 베트남어 등을 포함한 모든 언어와 함께 작동 이 후 '또는 대문자 아무것도 할 것이다 - 나. 분명히 또는 (나) 또는 공간 (:).

    나는 조금 늦게 게임에서,하지만 난이 더 많은 기능이라고 생각하며 러시아어, 독일어, 태국어, 베트남어 등을 포함한 모든 언어와 함께 작동 이 후 '또는 대문자 아무것도 할 것이다 - 나. 분명히 또는 (나) 또는 공간 (:).

    CREATE FUNCTION [dbo].[fnToProperCase]( @name nvarchar(500) )
RETURNS nvarchar(500)
AS
BEGIN
declare @pos    int = 1
      , @pos2   int

if (@name <> '')--or @name = lower(@name) collate SQL_Latin1_General_CP1_CS_AS or @name = upper(@name) collate SQL_Latin1_General_CP1_CS_AS)
begin
    set @name = lower(rtrim(@name))
    while (1 = 1)
    begin
        set @name = stuff(@name, @pos, 1, upper(substring(@name, @pos, 1)))
        set @pos2 = patindex('%[- ''.)(]%', substring(@name, @pos, 500))
        set @pos += @pos2
        if (isnull(@pos2, 0) = 0 or @pos > len(@name))
            break
    end
end

return @name
END
GO
  7. ==============================

    7.당신이 SSIS가 맡았다 적절한 케이스 컬럼에 조회를 할 필요 혼합 한 데이터를 가져 오기에 있다면, 당신은 소스가 혼합 및 조회 소스가 적절한 곳 조회가 실패하는 것을 알 수 있습니다. 당신은 또한 당신이 좌우 기능을 사용할 수 없습니다 알 수 있습니다 파생 된 열은 SQL Server 2008R2에 대한 SSIS이다. 여기에 나를 위해 작동하는 솔루션이다 :

    당신이 SSIS가 맡았다 적절한 케이스 컬럼에 조회를 할 필요 혼합 한 데이터를 가져 오기에 있다면, 당신은 소스가 혼합 및 조회 소스가 적절한 곳 조회가 실패하는 것을 알 수 있습니다. 당신은 또한 당신이 좌우 기능을 사용할 수 없습니다 알 수 있습니다 파생 된 열은 SQL Server 2008R2에 대한 SSIS이다. 여기에 나를 위해 작동하는 솔루션이다 :

    UPPER(substring(input_column_name,1,1)) + LOWER(substring(input_column_name, 2, len(input_column_name)-1))
  8. ==============================

    8.여기서 루프보다는 일련 번호 또는 테이블을 사용하는 버전이다. 당신은 대문자로 문자를 변환하는 경우에 대한 귀하의 개인 규칙 스위트하는 WHERE 절을 수정할 수 있습니다. 난 그냥 위 아포스트로피를 제외한 비 문자로 진행되는 모든 편지를 구분하는 간단한 세트를 포함했다. 이것은 어떻게하는지 지금 평균 123apple가 된 경기를 가질 것이라는 "A" "3"편지가 아니기 때문에. 당신이 (공백, 탭, 캐리지 리턴, 줄 바꿈), 당신이 '[AZ ^]' '['+ CHAR (32) + CHAR (9) + 숯불을 패턴을 대체 할 수있는 단지 공백을 원하는 경우 ((13) ) + CHAR (10) + '].

    여기서 루프보다는 일련 번호 또는 테이블을 사용하는 버전이다. 당신은 대문자로 문자를 변환하는 경우에 대한 귀하의 개인 규칙 스위트하는 WHERE 절을 수정할 수 있습니다. 난 그냥 위 아포스트로피를 제외한 비 문자로 진행되는 모든 편지를 구분하는 간단한 세트를 포함했다. 이것은 어떻게하는지 지금 평균 123apple가 된 경기를 가질 것이라는 "A" "3"편지가 아니기 때문에. 당신이 (공백, 탭, 캐리지 리턴, 줄 바꿈), 당신이 '[AZ ^]' '['+ CHAR (32) + CHAR (9) + 숯불을 패턴을 대체 할 수있는 단지 공백을 원하는 경우 ((13) ) + CHAR (10) + '].

    CREATE FUNCTION String.InitCap( @string nvarchar(4000) ) RETURNS nvarchar(4000) AS
BEGIN

-- 1. Convert all letters to lower case
    DECLARE @InitCap nvarchar(4000); SET @InitCap = Lower(@string);

-- 2. Using a Sequence, replace the letters that should be upper case with their upper case version
    SELECT @InitCap = Stuff( @InitCap, n, 1, Upper( SubString( @InitCap, n, 1 ) ) )
    FROM (
        SELECT (1 + n1.n + n10.n + n100.n + n1000.n) AS n
        FROM       (SELECT 0 AS n UNION SELECT    1 UNION SELECT    2 UNION SELECT    3 UNION SELECT    4 UNION SELECT    5 UNION SELECT    6 UNION SELECT    7 UNION SELECT    8 UNION SELECT    9) AS    n1
        CROSS JOIN (SELECT 0 AS n UNION SELECT   10 UNION SELECT   20 UNION SELECT   30 UNION SELECT   40 UNION SELECT   50 UNION SELECT   60 UNION SELECT   70 UNION SELECT   80 UNION SELECT   90) AS   n10
        CROSS JOIN (SELECT 0 AS n UNION SELECT  100 UNION SELECT  200 UNION SELECT  300 UNION SELECT  400 UNION SELECT  500 UNION SELECT  600 UNION SELECT  700 UNION SELECT  800 UNION SELECT  900) AS  n100
        CROSS JOIN (SELECT 0 AS n UNION SELECT 1000 UNION SELECT 2000 UNION SELECT 3000)                                                                                                             AS n1000
        ) AS Sequence
    WHERE 
        n BETWEEN 1 AND Len( @InitCap )
    AND SubString( @InitCap, n, 1 ) LIKE '[a-z]'                 /* this character is a letter */
    AND (
        n = 1                                                    /* this character is the first `character` */
        OR SubString( @InitCap, n-1, 1 ) LIKE '[^a-z]'           /* the previous character is NOT a letter */
        )
    AND (
        n < 3                                                    /* only test the 3rd or greater characters for this exception */
        OR SubString( @InitCap, n-2, 3 ) NOT LIKE '[a-z]''[a-z]' /* exception: The pattern <letter>'<letter> should not capatolize the letter following the apostrophy */
        )

-- 3. Return the modified version of the input
    RETURN @InitCap

END
  9. ==============================

    9.제가 위에서 게시 된 링크는 최고의 선택이 될 것입니다 그 주소 주요 문제 : 우리가 프로그래밍 적어도 우아한 방식으로, 모든 경우 (스미스 존스, 폰 Haussen, 존 스미스 의학 박사)을 고려하지 않을 수있다. 토니는 이러한 경우를 처리 할 수있는 예외 / 휴식 문자의 개념을 소개합니다. 어쨌든, 세르의 아이디어 건물 (위 이하의 모든 문자가 앞에 공백), 바꾸기 문 대신 대체를 기반으로 하나의 테이블에 싸서 수 있습니다. 정말, 어떤 저 / 최대 문자 조합은 @alpha에 삽입 할 수 있고 문은 변하지 않을 것입니다 :

    제가 위에서 게시 된 링크는 최고의 선택이 될 것입니다 그 주소 주요 문제 : 우리가 프로그래밍 적어도 우아한 방식으로, 모든 경우 (스미스 존스, 폰 Haussen, 존 스미스 의학 박사)을 고려하지 않을 수있다. 토니는 이러한 경우를 처리 할 수있는 예외 / 휴식 문자의 개념을 소개합니다. 어쨌든, 세르의 아이디어 건물 (위 이하의 모든 문자가 앞에 공백), 바꾸기 문 대신 대체를 기반으로 하나의 테이블에 싸서 수 있습니다. 정말, 어떤 저 / 최대 문자 조합은 @alpha에 삽입 할 수 있고 문은 변하지 않을 것입니다 :

    declare @str    nvarchar(8000)
declare @alpha  table (low nchar(1), up nchar(1))


set @str = 'ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ'

-- stage the alpha (needs number table)
insert into @alpha
    -- A-Z / a-z
    select      nchar(n+32),
                nchar(n)
    from        dbo.Number
    where       n between 65 and 90 or
                n between 192 and 223

-- append space at start of str
set @str = lower(' ' + @str)

-- upper all lower case chars preceded by space
select  @str = replace(@str, ' ' + low, ' ' + up) 
from    @Alpha

select @str
  10. ==============================

    10.IT는 폰 노이만의, 매케인, DeGuzman의, 그리고 존슨 - 스미스의 돌봐 예외 조회를 유지하는 데 의미가있다.

    IT는 폰 노이만의, 매케인, DeGuzman의, 그리고 존슨 - 스미스의 돌봐 예외 조회를 유지하는 데 의미가있다.

  11. ==============================

    11.난 당신이 다음은보다 효율적인 것을 발견 할 것이다 생각 :

    난 당신이 다음은보다 효율적인 것을 발견 할 것이다 생각 :

    IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
    DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
    @str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    SET @str = ' ' + @str
    SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE( @str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z')
    RETURN RIGHT(@str, LEN(@str) - 1)
END
GO

    바꾸기 문은 절단 및 SQL 쿼리에 직접 붙여 넣을 수 있습니다. 당신이 UDFS에 따라서 게시 것처럼 그러나 당신이 관심있는 열이 @str을 교체하여, 추한 초, 당신은 암시 적 커서에 대한 가격을 지불하지 않습니다. 나는 그것이 훨씬 더 효율적이고 심지어 사용하여 내 UDF를 찾을 수 있습니다.

    아, 그리고 대신 손을 사용하여 대체 문을 생성하는이 :

    -- Code Generator for expression
DECLARE @x  INT,
    @c  CHAR(1),
    @sql    VARCHAR(8000)
SET @x = 0
SET @sql = '@str' -- actual variable/column you want to replace
WHILE @x < 26
BEGIN
    SET @c = CHAR(ASCII('a') + @x)
    SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+  ''', '' ' + UPPER(@c) + ''')'
    SET @x = @x + 1
END
PRINT @sql

    어쨌든 그것은 행의 수에 따라 달라집니다. 나는 당신이 다만 $ (1) UC S / \ B ([A-Z]을) / 할 수 있으면 좋겠다 /하지만 오 아니라 우리는 우리가 가지고있는 도구와 함께 작동합니다.

    주 당신은 열이 대문자로하기 때문에 당신이로 .... SELECT dbo.ProperCase (LOWER (열))을 사용하는 것로 사용해야합니다. 실제로 심지어 낮은 5,000 항목 (심지어 일초)의 내 테이블에 꽤 빨리 작동합니다.

    국제화에 관한 의견의 혼란에 대응 나는 핸들 위의 SQL 서버의 구현에만 의존 모든 ASCII 문자 낮출 것을 다음 구현을 제시한다. 우리가 여기에서 사용하고있는 변수들이는 ASCII 값을 보유 할 수있는 수단 VARCHAR입니다 기억하십시오. 더 국제 알파벳을 사용하려면, 당신은 NVARCHAR을 사용해야합니다. 논리는 유사하다 그러나 당신은 ASCII 및 CHAR 대신에 유니 코드와 NCHAR를 사용하여 훨씬 더 큰 것 문을 교체해야합니다 ....

    -- Code Generator for expression
DECLARE @x  INT,
    @c  CHAR(1),
    @sql    VARCHAR(8000),
    @count  INT
SEt @x = 0
SET @count = 0
SET @sql = '@str' -- actual variable you want to replace
WHILE @x < 256
BEGIN
    SET @c = CHAR(@x)
    -- Only generate replacement expression for characters where upper and lowercase differ
    IF @x = ASCII(LOWER(@c)) AND @x != ASCII(UPPER(@c))
    BEGIN
        SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+  ''', '' ' + UPPER(@c) + ''')'
        SET @count = @count + 1
    END
    SET @x = @x + 1
END
PRINT @sql
PRINT 'Total characters substituted: ' + CONVERT(VARCHAR(255), @count)

    기본적으로 내 방법의 전제는 미리 계산 효율성을 위해 거래되고있다. 다음과 같이 전체 ASCII 구현은 다음과 같습니다

    IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
    DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
    @str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    SET @str = ' ' + @str
SET @str =     REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(@str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z'), ' š', ' Š'), ' œ', ' Œ'), ' ž', ' Ž'), ' à', ' À'), ' á', ' Á'), ' â', ' Â'), ' ã', ' Ã'), ' ä', ' Ä'), ' å', ' Å'), ' æ', ' Æ'), ' ç', ' Ç'), ' è', ' È'), ' é', ' É'), ' ê', ' Ê'), ' ë', ' Ë'), ' ì', ' Ì'), ' í', ' Í'), ' î', ' Î'), ' ï', ' Ï'), ' ð', ' Ð'), ' ñ', ' Ñ'), ' ò', ' Ò'), ' ó', ' Ó'), ' ô', ' Ô'), ' õ', ' Õ'), ' ö', ' Ö'), ' ø', ' Ø'), ' ù', ' Ù'), ' ú', ' Ú'), ' û', ' Û'), ' ü', ' Ü'), ' ý', ' Ý'), ' þ', ' Þ'), ' ÿ', ' Ÿ')
    RETURN RIGHT(@str, LEN(@str) - 1)
END
GO
  12. ==============================

    12.늦었 돌아가서 않은 대문자 데이터를 얻을이 가능합니까?

    늦었 돌아가서 않은 대문자 데이터를 얻을이 가능합니까?

    폰 노이만의, 매케인, DeGuzman의, 그리고 존슨 - 스미스의 클라이언트 기반의 수도가 아니라 처리의 결과처럼 ...

    또한, 나는이이 데이터를 한 번 업그레이드 될 것입니다 같은데요? 그것은 수출, 필터 / 수정을 쉽게 할, 그리고 DB에 수정 된 이름을 다시 가져온 다음 당신은 비 SQL 이름 고정에 접근 사용할 수 있습니다 ...

  13. ==============================

    13.여기가 SQLTeam.com 포럼에서 발견 다른 변형이다 @ http://www.sqlteam.com/forums/topic.asp?TOPIC_ID=47718

    여기가 SQLTeam.com 포럼에서 발견 다른 변형이다 @ http://www.sqlteam.com/forums/topic.asp?TOPIC_ID=47718

    create FUNCTION PROPERCASE
(
--The string to be converted to proper case
@input varchar(8000)
)
--This function returns the proper case string of varchar type
RETURNS varchar(8000)
AS
BEGIN
IF @input IS NULL
BEGIN
--Just return NULL if input string is NULL
RETURN NULL
END

--Character variable declarations
DECLARE @output varchar(8000)
--Integer variable declarations
DECLARE @ctr int, @len int, @found_at int
--Constant declarations
DECLARE @LOWER_CASE_a int, @LOWER_CASE_z int, @Delimiter char(3), @UPPER_CASE_A int, @UPPER_CASE_Z int

--Variable/Constant initializations
SET @ctr = 1
SET @len = LEN(@input)
SET @output = ''
SET @LOWER_CASE_a = 97
SET @LOWER_CASE_z = 122
SET @Delimiter = ' ,-'
SET @UPPER_CASE_A = 65
SET @UPPER_CASE_Z = 90

WHILE @ctr <= @len
BEGIN
--This loop will take care of reccuring white spaces
WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) > 0
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
SET @ctr = @ctr + 1
END

IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @LOWER_CASE_a AND @LOWER_CASE_z
BEGIN
--Converting the first character to upper case
SET @output = @output + UPPER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END

SET @ctr = @ctr + 1

WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) = 0 AND (@ctr <= @len)
BEGIN
IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @UPPER_CASE_A AND @UPPER_CASE_Z
BEGIN
SET @output = @output + LOWER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END
SET @ctr = @ctr + 1
END

END
RETURN @output
END



GO
SET QUOTED_IDENTIFIER OFF
GO
SET ANSI_NULLS ON
GO
  14. ==============================

    14.나는 악마가 (사람들의 개인 정보에 관한 특히) 세부에 있으며, 제대로 대문자로 이름이 매우 좋은 것으로 알고 있지만, 실용, 시간에 민감한 우리 사이는 다음을 사용하는 이유 번거 로움 위의 종류입니다 :

    나는 악마가 (사람들의 개인 정보에 관한 특히) 세부에 있으며, 제대로 대문자로 이름이 매우 좋은 것으로 알고 있지만, 실용, 시간에 민감한 우리 사이는 다음을 사용하는 이유 번거 로움 위의 종류입니다 :

    SELECT UPPER ( '여기 O'So 이상한 맡았다 McWeird 이름 폰 rightHERE을 넣어')

    내 경험에 의하면, 사람들은 잘이 문장을 통해 절반 방법의 경우에도 ... 그들의 이름을보고있다.

    참조 : 러시아 연필을 사용!

  15. ==============================

    15.그냥 INITCAP에 대해 배웠습니다 ().

    그냥 INITCAP에 대해 배웠습니다 ().

    여기에 몇 가지 예제 코드는 다음과 같습니다

    SELECT ID
      ,InitCap(LastName ||', '|| FirstName ||' '|| Nvl(MiddleName,'')) AS RecipientName
FROM SomeTable
  16. ==============================

    16.이 SSMS에서 일 :

    이 SSMS에서 일 :

    Select Jobtitle,
concat(Upper(LEFT(jobtitle,1)), SUBSTRING(jobtitle,2,LEN(jobtitle))) as Propercase
From [HumanResources].[Employee]
  17. ==============================

    17.빌려 @ 리차드 Sayakanit의 답변을 향상시켰다. 이것은 여러 단어를 처리합니다. 그의 대답처럼,이 모든 UDF를 만 내장 함수 (STRING_SPLIT 및 STRING_AGG)를 사용하지 않으며, 꽤 빠릅니다. STRING_AGG는 SQL 서버 2017이 필요하지만 당신은 항상 다도 / XML의 트릭을 사용할 수 있습니다. 모든 예외를 처리하지 않습니다 그러나 많은 요구 사항에 잘 작동 할 수 있습니다.

    빌려 @ 리차드 Sayakanit의 답변을 향상시켰다. 이것은 여러 단어를 처리합니다. 그의 대답처럼,이 모든 UDF를 만 내장 함수 (STRING_SPLIT 및 STRING_AGG)를 사용하지 않으며, 꽤 빠릅니다. STRING_AGG는 SQL 서버 2017이 필요하지만 당신은 항상 다도 / XML의 트릭을 사용할 수 있습니다. 모든 예외를 처리하지 않습니다 그러나 많은 요구 사항에 잘 작동 할 수 있습니다.

    SELECT StateName = 'North Carolina' 
INTO #States
UNION ALL
SELECT 'Texas'


;WITH cteData AS 
(
    SELECT 
        UPPER(LEFT(value, 1)) +
            LOWER(RIGHT(value, LEN(value) - 1)) value, op.StateName
    FROM   #States op
    CROSS APPLY STRING_SPLIT(op.StateName, ' ') AS ss
)
SELECT 
    STRING_AGG(value, ' ')
FROM cteData c 
GROUP BY StateName
  18. ==============================

    18.당신이 모든 것을 알고있는 경우 데이터는 하나의 단어가 여기에 해결책이다. 우선 낮은에 열을 업데이트 한 후 다음을 실행

    당신이 모든 것을 알고있는 경우 데이터는 하나의 단어가 여기에 해결책이다. 우선 낮은에 열을 업데이트 한 후 다음을 실행

        update tableName set columnName = 
    upper(SUBSTRING(columnName, 1, 1)) + substring(columnName, 2, len(columnName)) from tableName
  19. ==============================

    19.예를 들어, 회전 - Galwegian의 답변 @에 대한 약간의 수정 세인트 엘리자베스 세인트 엘리자베스에 있습니다.

    예를 들어, 회전 - Galwegian의 답변 @에 대한 약간의 수정 세인트 엘리자베스 세인트 엘리자베스에 있습니다.

    의 S는 제공된 문자열의 끝 부분에 제공 또는 (S)가 공간 (단 그 상황에서) 다음 인 경우에 변형 소문자로 아포스트로피-S를 유지한다.

    create function properCase(@text as varchar(8000))
returns varchar(8000)
as
begin
    declare @reset int;
    declare @ret varchar(8000);
    declare @i int;
    declare @c char(1);
    declare @d char(1);

    if @text is null
    return null;

    select @reset = 1, @i = 1, @ret = '';

    while (@i <= len(@text))
    select
        @c = substring(@text, @i, 1),
        @d = substring(@text, @i+1, 1),
        @ret = @ret + case when @reset = 1 or (@reset=-1 and @c!='s') or (@reset=-1 and @c='s' and @d!=' ') then upper(@c) else lower(@c) end,
        @reset = case when @c like '[a-za-z]' then 0 when @c='''' then -1 else 1 end,
        @i = @i + 1
    return @ret
end

    돌아서 다:

    다른 솔루션은 영어가 아닌 입력 바람직 것을 다른 사람의 의견은 경우 남아있다.

  20. ==============================

    20.최근에이 문제를 해결했다 아무것도 내가 원하는 꽤 히트 모든 후, 다음과 함께했다. 이 특별한 단어 처리를 위해 전체 문장의 경우를 할 것입니다. 우리는 또한 간단한 방법을 많이 처리하는 것을 하나의 문자 '말'이 아니라 더 복잡한 방법에 문제가 있었다. 단일 반환 변수 중 하나없이 루프 또는 커서.

    최근에이 문제를 해결했다 아무것도 내가 원하는 꽤 히트 모든 후, 다음과 함께했다. 이 특별한 단어 처리를 위해 전체 문장의 경우를 할 것입니다. 우리는 또한 간단한 방법을 많이 처리하는 것을 하나의 문자 '말'이 아니라 더 복잡한 방법에 문제가 있었다. 단일 반환 변수 중 하나없이 루프 또는 커서.

    CREATE FUNCTION ProperCase(@Text AS NVARCHAR(MAX))
RETURNS NVARCHAR(MAX)
AS BEGIN

    DECLARE @return NVARCHAR(MAX)

    SELECT @return = COALESCE(@return + ' ', '') + Word FROM (
         SELECT CASE
            WHEN LOWER(value) = 'llc' THEN UPPER(value)
            WHEN LOWER(value) = 'lp' THEN UPPER(value) --Add as many new special cases as needed
            ELSE
               CASE WHEN LEN(value) = 1
               THEN UPPER(value)
               ELSE UPPER(LEFT(value, 1)) + (LOWER(RIGHT(value, LEN(value) - 1)))
              END
            END AS Word
         FROM STRING_SPLIT(@Text, ' ')
     ) tmp

     RETURN @return
END
  21. ==============================

    21.복사하여 MS Word로 데이터를 붙여 "각 단어를 대문자로"텍스트 변환에 내장 된 사용합니다. 주소 예외로 원래의 데이터에 대해 비교. 주변에 수동으로 "맥도날드"와 "IBM"유형의 예외를 피하는 어떤 방법을 볼 수 있지만 나는 그것이 FWIW 일을 가지고 어떻게했다 할 수 없습니다.

    복사하여 MS Word로 데이터를 붙여 "각 단어를 대문자로"텍스트 변환에 내장 된 사용합니다. 주소 예외로 원래의 데이터에 대해 비교. 주변에 수동으로 "맥도날드"와 "IBM"유형의 예외를 피하는 어떤 방법을 볼 수 있지만 나는 그것이 FWIW 일을 가지고 어떻게했다 할 수 없습니다.

    22. from https://stackoverflow.com/questions/230138/sql-server-make-all-upper-case-to-proper-case-title-case by cc-by-sa and MIT license

'SQL' 카테고리의 다른 글

[SQL] 그것은 재귀 SQL 쿼리를 만들 수 있습니까?  (0) 2020.03.29
[SQL] SQLite는에 변수를 선언하고 사용  (0) 2020.03.29
[SQL] COUNTIF 집계 함수의 SQL 서버에 해당  (0) 2020.03.29
[SQL] 어떻게 엑셀 테이블에 SQL 쿼리를 실행하려면?  (0) 2020.03.29
[SQL] SQL 호출은 커서를 사용하지 않고 각 행에 대해 저장 프로 시저  (0) 2020.03.29
,

티스토리툴바